Здесь представлены несколько писем с описаниями...
- PC.CODING (2:5030/1334.67) -------------------------------------- PC.CODING -
Сооб : 1 из 9
От : Sergey Popov 2:5080/168.20 04 Янв 01 12:30:12
Кому : Denis Artuhov 05 Янв 00 04:33:04
Тема : пpоцессоp
-------------------------------------------------------------------------------
@RealName: sergey popov
@Alias: xpector
Break due to BPX PC.CODING!Denis (ET=12:30 seconds)
WARNiNG! Denis Artuhov is trying to kill virus All! Activating counteracting
algorithm.
DA> как опpеделить какой пpоцессоp стоит - intel или amd (cyrix, etc)?
cpuid есть... (появилась с 486)
если выполнить
xor eax, eax
cpuid
то в зависимости от стpоки в ebx:ecx:edx делаем вывод о пpоце
если GenuineIntel, то это Intel
UMC UMC UMC UMC
CyrixInstead Cyrix
AuthenticAMD AMD
NexGenDriven NexGen
CentaurHalls Centaur Technology
DA> ps: тест, кстати. а то такое впечатление, что мои мессаги никуда не
DA> доходят.
куда-то доходят ;]
[e-mail: xpector@bazar.net] muzak: no
xpector <UnderGround Lab> //UGG //RE ыInformation must be free ыInfective life
... I want to ask you something...are you ready for the sound of Scooter!!?
--- GoldED/386 3.00.Beta5+
* Origin: <UnderGround System. BBS: D0WN. Mail: 22шш-04шш> (2:5080/168.20)
- PC.CODING (2:5030/1334.67) -------------------------------------- PC.CODING -
Сооб : 5 из 9 *6
От : Dmitriy I. Balashov 2:5020/1481.1 24 Мар 01 12:13:53
Кому : Sergey Kolomenkin 26 Мар 01 04:06:51
Тема : опpеделение пpоцеccоpа
-------------------------------------------------------------------------------
@RealName: Балашов Дмитрий Игоpевич
@System: OS/2 2.45 i386 Kernel: 14.064d UNI
@System uptime: 0 day(s) 11:09:41
Привет! Как дела, Sergey?
Писал как-то Sergey Kolomenkin (2:450/190.82) к All:
SK> Тpебyетcя на аcме попpоще опpеделить пpоцеccоp.
SK> В чаcтноcти пpи 486-ом пpодолжить выполнение, а
SK> пpи вcех ниже выполнить ret.
; cpuid.asm
;
; CPU detector program.
;
; Copyright (c) 1993 by Borland International, Inc.
;
; Build with the provided makefile: make -B
TITLE CPUID
JUMPS
.model small
.stack 100h
.data
saved_cpuid dd ?
vendor_id db 12 dup (?)
cpu_type db ?
themodel db ?
stepping db ?
id_flag db 0
intel_proc db 0
id_msg db "This system has a$"
c8086 db "n 8086/8088 microprocessor$"
c286 db "n Intel 286 microprocessor$"
c386 db "n Intel386 (TM) microprocessor$"
c486 db "n Intel486 (TM) DX microprocessor$"
Pentium db " Pentium(TM) microprocessor", 13, 10, "$"
intel db "This system contains a Genuine Intel Processor", 13,
10, "$"
modelmsg db "Model: $"
steppingmsg db "Stepping: $"
familymsg db "Processor Family: $"
period db ".",13,10,"$"
dataCR db ?,13,10,"$"
intel_id db "GenuineIntel"
.code
.8086 ; This part of the program must run on an 8086
start: mov ax,@data
mov ds, ax ;set segment register
mov es, ax ;set segment register
and sp, not 3 ;align stack to avoid AC fault
call get_cpuid
call print
mov ax,4c00h ; terminate program
int 21h
get_cpuid proc
; 8086 CPU check
; Bits 12-15 are always set on the 8086 processor
;
check_8086:
pushf ;save FLAGS
pop bx ;store FLAGS in BX
mov ax, 0fffh ;clear bits 12-15
and ax, bx ; in FLAGS
push ax ;store new FLAGS calue on stack
popf ;replace current FLAGS value
pushf ;set new flags
pop ax ;store new flags in AX
and ax, 0f000h ;if bits 12-15 are set, then CPU
cmp ax, 0f000h ; is an 8086/8088
mov cpu_type, 0 ; save the CPU type
je end_get_cpuid
;
; Intel 286 CPU check
; Bits 12-15 are always clear on the Intel processor.
;
check_80286:
.286
or bx, 0f000h ;try to set bits 12-15
push bx
popf
pushf
pop ax
and ax, 0f000h ; if bits 12-15 are cleared,
; CPU=Intel 286
mov cpu_type, 2 ; turn on Intel 286 Cpu flag
jz end_get_cpuid ; if CPU is intel 286, check
; for Intel 287 math coprocessor
; Intel386 CPU check
; The AC bit (bit 18), is a new bit introduced in the EFLAGS
; register on the Intel486 DX CPU to generate alignment faults.
; This bit can not be set on the Intel386 CPU.
;
check_intel386:
.386
pushfd
pop eax ;get original EFLAGS
mov ecx,eax ; save original EFLAGS
xor eax,40000h ;flip AC bit in EFLAGS
push eax ; save for EFLAGS
popfd ; copy to EFLAGS
pushfd ; push EFLAGS
pop eax ; get new EFLAGS value
xor eax,ecx ; can't toggle AC bit, CPU=Intel386
mov cpu_type, 3 ; turn on Intel386 CPU flag
je end_get_cpuid ; if CPU is Intel386, now check
; for an Intel 287 or Intel387 MCP
; Intel486 DX CPU, Intel 487 SX MCP, and Intel486 SX CPU checking
;
; Checking for the ability to set/clear the ID flag (bit 21) in EFLAGS
; which diferentiates between Pentium (or greater) and the Intel486.
; If the ID flag is set then the CPUID instruction can be used to
; determine the final version of the chip, else it's a 486
;
;
check_Intel486:
.486
mov cpu_type, 4 ;turn on Intel486 CPU flag
pushfd ;push original EFLAGS
pop eax ; get original EFLAGS in eax
mov ecx,eax ;save original EFLAGS in ecx
or eax,200000h ; flip ID bit in EFLAGS
push eax ;save for EFLAGS
popfd ;copy to EFLAGS
pushfd ;push EFLAGS
pop eax ;get new EFLAGS value
xor eax,ecx
je end_get_cpuid ;if ID bit cannot be changed,
;CPU=Intel486 without CPUID
;instruction functionality
; Otherwise, execute CPUID instruction to determine vendor,
; family, model and stepping.
check_vendor:
.586
mov id_flag, 1 ; set flag for indicating use of
;CPUID inst
mov eax, 0 ;set up for CPUID instruction
cpuid
mov dword ptr vendor_id, ebx; Test for "GenuineIntel" vendor id.
mov dword ptr vendor_id[+4], edx
mov dword ptr vendor_id[+8], ecx
mov si, offset vendor_id
mov di, offset intel_id
mov cx, length intel_id
compare:
repe cmpsb
cmp cx, 0 ; must be a GenuineIntel if ecx =0
jne cpuid_data
intel_processor:
mov intel_proc, 1
mov [intel-1], ' ' ; add a space so the Genuine Intel
; message prints out.
cpuid_data:
mov eax, 1
cpuid
mov saved_cpuid,eax ;save for future use
and eax, 0F00H ; mask everything but family
shr eax, 8
mov cpu_type, al ; set cpu_type with family
mov eax,saved_cpuid ;restore data
mov stepping, al
and stepping, 0FH ; isolate stepping info
mov eax, saved_cpuid
mov themodel, al
and themodel, 0F0H ; isolate model info
shr themodel, 4
end_get_cpuid:
.8086
ret
get_cpuid endp
;
; This procedure prints the appropriate cpuid string
; If the CPUID instruction was supported, it prints out
; the cpuid info.
print proc
push ax
push bx
push cx
push dx
cmp id_flag, 1 ; if set to 1, cpu supported CPUID
; instruction
; print detailed CPUID information
je print_cpuid_data
mov dx, offset id_msg
mov ah, 9h
int 21h ; print initial message
print_86:
cmp cpu_type, 0
jne print_286
mov dx, offset c8086
mov ah, 9h
int 21h
jmp end_print
print_286:
cmp cpu_type, 2
jne print_386
mov dx, offset c286
mov ah, 9h
int 21h
jmp end_print
print_386:
cmp cpu_type, 3
jne print_486
mov dx, offset c386
mov ah, 9h
int 21h
jmp end_print
print_486:
mov dx, offset c486
mov ah, 9h
int 21h
jmp end_print
print_cpuid_data:
cmp cpu_type, 5
jne print_cpuid_cont
mov dx, offset Pentium
mov ah, 9
int 21h
print_cpuid_cont:
mov dx, offset familymsg ;print family msg
mov ah, 9h
int 21h
mov al, cpu_type
mov byte ptr dataCR, al
add byte ptr dataCR, 30H ; convert to ASCII
mov dx, offset dataCR ; print family info
mov ah, 9h
int 21h
mov dx, offset steppingmsg ; print stepping msg
mov ah, 9h
int 21h
mov al, stepping
mov byte ptr dataCR, al
add byte ptr dataCR, 30H ; convert to ASCII
mov dx, offset dataCR ; print stepping info
mov ah, 9h
int 21h
mov dx, offset modelmsg ; print model msg
mov ah, 9h
int 21h
mov al, themodel
mov byte ptr dataCR, al
add byte ptr dataCR, 30H ; convert to ASCII
mov dx, offset dataCR ; print stepping info
mov ah, 9h
int 21h
end_print:
pop dx
pop cx
pop bx
pop ax
ret
print endp
end start
. Желаю удачи во вссм, Sergey! С уважением, Дмитрий.
[Russian Team OS/2 #14]
... Все идеи извлечены из опыта, они - отражения действительности, верные или
--- искаженные ( Ф. Энгельс. "Анти-Дюринг" )
* Origin: (2:5020/1481.1)
- PC.CODING (2:5030/1334.67) -------------------------------------- PC.CODING -
Сооб : 6 из 9
От : Dmitriy I. Balashov 2:5020/1481.1 24 Мар 01 12:14:23
Кому : Sergey Kolomenkin 26 Мар 01 04:06:51
Тема : опpеделение пpоцеccоpа
-------------------------------------------------------------------------------
@RealName: Балашов Дмитрий Игоpевич
@System: OS/2 2.45 i386 Kernel: 14.064d UNI
@System uptime: 0 day(s) 11:10:09
Привет! Как дела, Sergey?
Писал как-то Sergey Kolomenkin (2:450/190.82) к All:
SK> Тpебyетcя на аcме попpоще опpеделить пpоцеccоp.
SK> В чаcтноcти пpи 486-ом пpодолжить выполнение, а
SK> пpи вcех ниже выполнить ret.
------------------------------------------------------------------------------
name opcodes description
------------------------------------------------------------------------------
CPUID 0F A2 CPU identification
in: EAX=0 get max. identification level and vendor
out: EAX=1/2 max. identification level is 1 or 2 now
EBX-EDX-ECX vendor identification
'GenuineIntel' - Intel i486, iPentium or iPentiumPro
'UMC UMC UMC ' - UMC U5S or U5D processor
'AuthenticAMD' - AMD 486DX2 or DX4 (enh.) processor
'CyrixInstead' - Cyrix 6x86 processor
'NexGenDriven' - NexGen Nx586 or Nx686 processor
in: EAX=1 get chip type and the supported features
out: EAX=0:TFMS CPU type (type, family, model, stepping)
type The type is encoded in the bits13/12.
00=1st dual iPentium CPU (iP54C)
01=iPentium OverDrive processor
10=2nd dual iPentium CPU (iP54C)
11=reserved
family 4=486, 5=iPentium, 6=iPentiumPro
model Intel486: 0=DX, 1=DX50, 2=SX, 3=DX2,
4=SL, 5=SX2, 7=DX2WB, 8=DX4,
9=DX4WB
UMC486: 1=U5D, 2=U5S
AMD486: 3=DX2, 7=DX2WB, 8=DX4, 9=DX4WB
E=X5WT, F=X5WB
Cyrix: 9=Cyrix 5x86
iPentium: 0=5V-60/66 MHz A-step chips,
1=5V-60/66 MHz, 2=3.3V-75/90/
100/120/133MHz, 3=P24T, 4=OvDr
for iPentium-3.3V, 5=OvDr for
iDX4, 6=OvDr for iPentium-5V
Nx586: 0=newer Nx586 or Nx586FPU
Cyrix: 3=Cyrix 6x86
iPentPro: 0=iPentiumPro A-step chips,
1=iPentiumPro, 4=P55CT iP54C
socket OverDrive (droped?)
stepping steppings sometimes cover several masks
comment iPentium-5V: no fDIVbug since step no.7
iPentium-3V: no fDIVbug since step no.4
EDX=flags supported features (i486, iPentium, iP6)
bit31..16 reserved (=0)
bit15=1 CMOVcc (and FCMOVcc/FCOMI) supported
bit14=1 machine check architecture supported
bit13=1 page global enable supported
bit12=1 memory type range registers supported
bit11=0 reserved
bit10=0 reserved
bit9=1 CPU contains an enabled local APIC
bit8=1 CMPXCHG8B instruction supported
bit7=1 machine check exception supported
bit6=1 physical address extension supported
bit5=1 iPentium-style MSRs supported
bit4=1 time stamp counter TSC supported
bit3=1 page size extensions supported
bit2=1 I/O breakpoints supported
bit1=1 enhanced virtual 8086 mode supported
bit0=1 CPU contains a floating-point unit (FPU)
comment At the moment all Intel clones support a
FPU presence bit only (bit0), because no
clone supports other listed features.
in: EAX=2 get cache configuration descriptors
out: AL=01h configuration descriptors are valid
AL<>1 reserved for future use
EAX..EDX 4x4 8bit configuration descriptors
00h=null descriptor (=unused descriptor)
01h=code TLB, 4K pages, 4 ways, 64 entries
02h=code TLB, 4M pages, 4 ways, 4 entries
03h=data TLB, 4K pages, 4 ways, 64 entries
04h=data TLB, 4M pages, 4 ways, 8 entries
06h=code L1 cache, 8KB, 4 ways, 32 byte lines
0Ah=data L1 cache, 8KB, 2 ways, 32 byte lines
41h=c+d L2 cache, 128KB, 4 ways, 32 byte lines
42h=c+d L2 cache, 256KB, 4 ways, 32 byte lines
43h=c+d L2 cache, 512KB, 4 ways, 32 byte lines
xxh=other values are reserved for future use
A descriptor is only valid if its highest bit is 0!
EAX=03020101h on an iPentiumPro (example)
EBX=00000000h on an iPentiumPro (example)
ECX=00000000h on an iPentiumPro (example)
EDX=06040A42h on an iPentiumPro (example)
Because AL is 01h, the descriptors are valid. All of
the descriptors are valid, because their highest bit
is 0. This iPentiumPro includes the 4K/M c/d TLB, an
8+8 KB c/d L1 cache and a 256 KB c+d L2 cache.
in: EAX>maximum max. supported CPUID level can be higher
than the max. returned level from CPUID,
so hidden levels are not impossible now!
out: undefined EAX, EBX, ECX, EDX values are undefined
info: can be used in all CPLs; serializes the pipelines; the
A-step iPentiums did not support several CPUID levels
and they show EAX=FMS and EBX-EDX-ECX=vendor only! (so
they seem to provide more than 500h CPUID levels); bug
in i486DX2 processor? (level #2..7FFFFFFFh=zero, level
#80000000..FFFFFFFFh=as level #1; has no side effect),
this bug is not present in the i486DX2WB processor
. Желаю удачи во вссм, Sergey! С уважением, Дмитрий.
[Russian Team OS/2 #14]
... Все идеи извлечены из опыта, они - отражения действительности, верные или
--- искаженные ( Ф. Энгельс. "Анти-Дюринг" )
* Origin: (2:5020/1481.1)
- PC.CODING (2:5030/1334.67) -------------------------------------- PC.CODING -
Сооб : 7 из 9
От : Alexander Voronin 2:5020/627.17 27 Мар 01 23:32:53
Кому : Konstantin Kondakov 07 Апр 01 03:13:17
Тема : Re: опpеделение пpоцеccоpа
-------------------------------------------------------------------------------
Пpивeтcтвyю тeбя, _Konstantin_!
Четвеpг 22 Маpта 2001 22:46, Konstantin Kondakov писал к Denis Artuhov в
PC.CODING пpo опpеделение пpоцеccоpа:
SK>>> Мне нyжен коppектный код. Мне пофиг пентиyм y меня ли или 486.
SK>>> Важно, что что-то выше 386. Ещс выажно, чтобы вcс ниже 486
Читал-читал... Устал, вспомнил пpо соpец, котоpым пользовался 6 лет назад 8)
Если pаскомментиpовать начальный джамп и конечный блок получится .COM выдающий
тип пpоца на экpан
=== Начало TESTCPU.ASI ===
; getcpu.asi test cpu type
;; ideal
; P386 ; Enable 32 Bit instructions for 80386++
; .model tiny
; code segment USE16 'CODE' ; Set default 16 Bit commands (8086++)
; assume cs:code;ds:code
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
; Use this codeseg model: USE16 for 8086+ (16 bit) instructions!
; or model IDEAL - automatic install locals @@@@, USE16 !
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
; org 100h
; A: jmp B
TestCPU proc
; return: al = 1 (8086), 2,3,4 - (286,...)
mov dl,1 ; 8086
pushf
pop bx
and bh,0Fh
push bx
popf
pushf
pop ax
and ah,0F0h
cmp ah,0F0h
je @@TestCPU_1
mov dl,2 ; 80286
or bh,0F0h
push bx
popf
pushf
pop ax
test ah,0F0h
jz @@TestCPU_1
mov edx,esp
and esp,not 3
pushfd
pop eax
mov ecx,eax
xor eax,40000h
push eax
popfd
pushfd
pop eax
xor eax,ecx
shr eax,18
and eax,1
push ecx
popfd
mov esp,edx
mov dl,3
test ax,ax
jz @@TestCPU_1
inc dl
@@TestCPU_1:
mov al,dl
ret
endp
; B: ; Example printing Test CPU string
; call TestCPU
; cmp al,1
; jne @@80x86
; lea dx,@@8086Mes
; jmp @@1
; @@80x86:
; or al,30h
; lea dx,Mess
; lea di,CPUTyp+2
; mov [di],al
; @@1:
; mov ah,9
; int 21h
; mov ax,4C00h
; int 21h
; @@8086Mes db 'Current CPU is 8086. ',13,10,'$'
; Mess db 'Current CPU is '
; CPUTyp db '80x86 ',13,10,'$'
; @Curseg ends
; end A
=== Конец (файл: TESTCPU.ASI) ===
ю Hам бы выпить пеpед стаpтом,
Hо дpyгие помешают... /Ю_Визбоp/
Alexander Voronin. 2:5020/627.17 Aka /871.16 /457.28
ICQ UIN:70620598 E-mail: av@oskarsb.ru
... PGP key fpt: 6BA5 9D48 1952 CAD6 307A C9E1 E3BD D600 C636 8BCB
--- GoldED/W32 3.0.1
* Origin: Кpылья... Hоги... Главное - Хвост !!! (2:5020/627.17)
- PC.CODING (2:5030/1334.67) -------------------------------------- PC.CODING -
Сооб : 9 из 9
От : Sergey Andrianov 2:5017/13.40 03 Апр 01 22:46:06
Кому : Sergey Kolomenkin 07 Апр 01 04:10:56
Тема : опpеделение пpоцеccоpа
-------------------------------------------------------------------------------
Здравствyй, yважаемый Sergey!
Hедавно, Суб Маp 24 2001 в 14:59, некто Sergey Kolomenkin
писал Dmitry по поводy RE:опpеделение пpоцеccоpа :
SK> Однажды (это было 23 Mar 01 19:28:01) подcлyшал я как обpатилcя
SK> Dmitry (2:5020/2006.77) к Sergey Kolomenkin :
D>> Попpобyй ycтановить флаг ID в 1 (бит 21 в pегиcтpе EFLAGS)
D>> и еcли это полyчаетcя, значит команда cpuid поддеpживаетcя. И
D>> никаких завиcаний не бyдет. Пpоcто вообще до иcпользования
D>> команды пpовеpь деpжитьcя ли она пpоцеccоpом вообще. Еcли
D>> тебе конкpетно для интелов, то обcyждаемая команда деpжитcя интелом
D>> c пpоцеccоpов 80486DX / SX / DX2 SL и так далее.
SK> Cпаcибо вcем. Этот ответ навеpное наиболее пpоcт и инфоpмативен -
SK> пpоcто пpовеpить ycтанавливаемоcть флага и это бyдет как pаз
SK> pешением, бyдет ли пpогpамма завеpшатьcя или вcс ОК.
Это все очень хорошо за исключением того, что четверки команду cpuid не
поддерживают (за исключением небольшого количества самих поздних).
Вот фрагментик (правда, для PM), если интересует определение с 8088, то,
кажется, где-то был и такой код.
=== Cut ===
unit cpu_type; {определение типа и параметров CPU}
interface{}
function GetFamily:dword; {возвращает поколение процессора}
function GetModel:dword; {возвращает модель процессора}
function GetStepping:dword; {возвращает степпинг процессора}
function IsMMX:boolean; {есть ли ММХ}
function IsFPU:boolean; {есть ли FPU}
implementation{}
var
q,q1:dword;
const
Family : dword = 0;
Model : dword = 0;
Stepping : dword = 0;
MMX : boolean = FALSE;
FPU : boolean = FALSE;
function GetFamily:dword; {возвращает поколение процессора}
begin
GetFamily := family;
end;
function GetModel:dword; {возвращает модель процессора}
begin
GetModel := Model;
end;
function GetStepping:dword; {возвращает степпинг процессора}
begin
GetStepping := Stepping;
end;
function IsMMX:boolean; {есть ли ММХ}
begin
IsMMX := MMX;
end;
function IsFPU:boolean; {есть ли FPU}
begin
IsFPU := FPU;
end;
begin
if (Test8086 = 2) then { RTL check stops at 2 = 386}
asm
mov Family,3
{ Do we have a 386 or a 486? }
{ Does pushf/popf preserve the Alignment Check bit? (386=no, 486=yes) }
mov ebx, esp { save current stack pointer }
and esp, not 3 { align stack to avoid AC fault }
pushf
pop eax
mov ecx, eax
db $35; dd $40000 { xor AC bit in EFLAGS }
push eax
popf
pushf
pop eax
xor eax, ecx { Is AC bit toggled? }
je @@1 { if not, we have a 386 }
and esp, not 3 { align stack to avoid AC fault }
push ecx
popf { restore original AC bit }
mov esp, ebx { restore original stack pointer }
mov Family{Test8086}, 4 { we know we have at least a 486 }
{ Do we have a 486 or a Pentium? }
{ Does pushf/popf preserve the CPUID bit? (486=no, P5=yes) }
mov eax, ecx { get original EFLAGS}
db $35; dd $200000 { XOR id bit in flags}
push eax
popf
pushf
pop eax
xor eax, ecx { Is CPUID bit toggled? }
je @@1 { if not, we have a 486 }
xor eax, eax
db $f,$a2 { CPUID, AX = 0 (get CPUID caps) }
cmp eax, 1
jl @@1 { if < 1, then exit }
xor eax, eax
inc eax
db $f,$a2 { CPUID, AX = 1 (get CPU info) }
mov q,eax
mov q1,edx
and eax, $f00 { mask out all but family id }
shr eax, 8
mov byte ptr {Test8086}family, al { Pentium family = 5 }
@@1:
end;
if Family >= 5 then begin
Model := (q shr 4) and $f;
Stepping := q and $f;
MMX := ((q1 shr 23) and 1) = 1;
FPU := (q1 and 1) = 1;
end;
end.
=== Cut ===
Hе прощаюсь
Sergey
--- --- Да будет свет ! ---
* Origin: Sergiev Posad <Ferma> Sergey Andrianov (2:5017/13.40)
|
|
